SIG/Bancos/CatBancos.aspx.vb

Option Explicit On
Option Strict On

Imports System.Data
Imports System.Linq
Imports Extensiones
Imports Microsoft.Reporting.WebForms

Partial Class Bancos_CatBancos
    Inherits ClsPaginas

    Private Property DtBan As DataTable
        Get
            DtBan = DirectCast(ViewState("DtBan"), DataTable)
        End Get

        Set(ByVal value As DataTable)
            ViewState("DtBan") = value
        End Set
    End Property

    Protected Sub Page_Load(sender As Object, e As System.EventArgs) Handles Me.Load
        If Not Page.IsPostBack Then
            ViewState("Orden") = ""
            CargaDatos()
        End If
    End Sub

    Public Sub CargaDatos()
        Dim ObjBancos As New ClsBancos
        If ObjBancos.GetBancos() Then
            ViewState("DTBancos") = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
            DtBan = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
            GlobalDTBancos = ObjBancos.DtResultados
        Else
            Me.GvDatos.DataSource = Nothing
        End If

        ObjBancos.Dispose()

        If ViewState("Orden").ToString() <> String.Empty Then
            CargaGrid(ViewState("Orden").ToString())
        Else
            CargaGrid("")
        End If
    End Sub

    Protected Sub LbAgregar_Click(sender As Object, e As System.EventArgs) Handles LbAgregar.Click
        Dim ObjBancos As New ClsBancos
        If ObjBancos.AddBancos(TxtBanco.Text.Trim, TxtEjecutivo.Text.Trim, TxtTelefono.Text.Trim, UsuarioActual.CveUsuario, UsuarioActual.CveEmpresa) Then
            TxtBanco.Text = ""
            TxtEjecutivo.Text = ""
            TxtTelefono.Text = ""
            Alert("El nuevo Banco se guardó correctamente.", TipoMensaje.MsgInformacion)
            UpTitulos.Update()
            ViewState("DTBancos") = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
            DtBan = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
            GlobalDTBancos = ObjBancos.DtResultados

            If ViewState("Orden").ToString() <> String.Empty Then
                CargaGrid(ViewState("Orden").ToString())
            Else
                CargaGrid("")
            End If
        End If
        ObjBancos.Dispose()
    End Sub

#Region "G V  D A T O S"
    Protected Sub GvDatos_RowDataBound(sender As Object, e As System.Web.UI.WebControls.GridViewRowEventArgs) Handles GvDatos.RowDataBound
        If e.Row.RowType = DataControlRowType.DataRow Then
            If e.Row.RowIndex = 0 Then
                e.Row.Cells(0).Width = Unit.Pixel(156) 'BANCO
                e.Row.Cells(1).Width = Unit.Pixel(206) 'EJECUTIVO
                e.Row.Cells(2).Width = Unit.Pixel(106) 'TELEFONO
                e.Row.Cells(3).Width = Unit.Pixel(95) 'ESTATUS
                e.Row.Cells(4).Width = Unit.Pixel(95) 'FECHA
                e.Row.Cells(5).Width = Unit.Pixel(100) 'USUARIO
                e.Row.Cells(6).Width = Unit.Pixel(100) 'EDITAR
                e.Row.Cells(7).Width = Unit.Pixel(65) 'ELIMINAR
            End If
            e.Row.Cells(0).HorizontalAlign = HorizontalAlign.Left
            e.Row.Cells(3).HorizontalAlign = HorizontalAlign.Center
            e.Row.Cells(4).HorizontalAlign = HorizontalAlign.Center
            e.Row.Cells(5).HorizontalAlign = HorizontalAlign.Center
            e.Row.Cells(6).HorizontalAlign = HorizontalAlign.Center
            e.Row.Cells(7).HorizontalAlign = HorizontalAlign.Center
        End If
    End Sub

    Protected Sub GvDatos_RowDeleting(sender As Object, e As System.Web.UI.WebControls.GridViewDeleteEventArgs) Handles GvDatos.RowDeleting
        Dim ObjBancos As New ClsBancos
        If ObjBancos.RemoveBancos(GvDatos.DataKeys(e.RowIndex).Value.ToString.ToEntero) Then
            GvDatos.EditIndex = -1
            ViewState("DTBancos") = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
            DtBan = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
            GlobalDTBancos = ObjBancos.DtResultados
            Alert("El Banco se eliminó correctamente.", TipoMensaje.MsgInformacion)
        End If

        ObjBancos.Dispose()

        If ViewState("Orden").ToString() <> String.Empty Then
            CargaGrid(ViewState("Orden").ToString())
        Else
            CargaGrid("")
        End If
    End Sub

    Protected Sub GvDatos_RowCancelingEdit(sender As Object, e As System.Web.UI.WebControls.GridViewCancelEditEventArgs) Handles GvDatos.RowCancelingEdit
        GvDatos.EditIndex = -1
        If ViewState("Orden").ToString() <> String.Empty Then
            CargaGrid(ViewState("Orden").ToString())
        Else
            CargaGrid("")
        End If
    End Sub

    Protected Sub GvDatos_RowUpdating(sender As Object, e As System.Web.UI.WebControls.GridViewUpdateEventArgs) Handles GvDatos.RowUpdating

        Dim ObjBancos As New ClsBancos
        ObjBancos.IniciaTransacSQL()

        Dim Banco As String = DirectCast(GvDatos.Rows(e.RowIndex).FindControl("TxtBanco"), TextBox).Text.Trim
        Dim Ejecutivo As String = DirectCast(GvDatos.Rows(e.RowIndex).FindControl("TxtEjecutivo"), TextBox).Text.Trim
        Dim Telefono As String = DirectCast(GvDatos.Rows(e.RowIndex).FindControl("TxtTelefono"), TextBox).Text.Trim
        Dim Estatus As Boolean = GvDatos.Rows(e.RowIndex).FCCheckBox("ChkEstatus").Checked
        Dim CveBanco As Integer = GvDatos.DataKeys(e.RowIndex).Value.ToString.ToEntero

        Dim TieneError As Boolean = False

        If ObjBancos.UpdateBancos(Banco, Ejecutivo, Telefono, Estatus, CveBanco) Then
            If ObjBancos.InhabilitarCuentasBancos(CveBanco, Estatus) Then
                GvDatos.EditIndex = -1
                ViewState("DTBancos") = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
                DtBan = ObjBancos.DtResultados.FiltraParametros("CveEmpresa = " & UsuarioActual.CveEmpresa)
                GlobalDTBancos = ObjBancos.DtResultados
                Alert("Los cambios se guardaron correctamente.", TipoMensaje.MsgInformacion)
            Else
                TieneError = True
            End If
        Else
            TieneError = True
        End If

        If TieneError Then
            ObjBancos.RollBack()
        Else
            ObjBancos.Commit()
            GlobalDTBancosCuentas(-1, CveEmpresa:=UsuarioActual.CveEmpresa) = Nothing
        End If

        ObjBancos.Dispose()

        If ViewState("Orden").ToString() <> String.Empty Then
            CargaGrid(ViewState("Orden").ToString())
        Else
            CargaGrid("")
        End If

    End Sub

    Protected Sub GvDatos_RowEditing(sender As Object, e As System.Web.UI.WebControls.GridViewEditEventArgs) Handles GvDatos.RowEditing
        GvDatos.EditIndex = e.NewEditIndex

        If ViewState("Orden").ToString() <> String.Empty Then
            CargaGrid(ViewState("Orden").ToString())
        Else
            CargaGrid("")
        End If
    End Sub
#End Region

#Region "O R D E N A M I E N T O"
    Protected Sub LbOrden_Click(ByVal sender As Object, ByVal e As EventArgs)
        Dim Orden As String = ""
        Dim Campo As String = ""
        Dim Literal As Literal = Nothing
        Const OrdenInicial As String = ""
        Dim Arg(2) As String

        Arg = CType(sender, LinkButton).CommandArgument().ToString.Split(";"c)
        Campo = Arg(0)
        Literal = CType(CType(sender, LinkButton).NamingContainer.FindControl("Img" & Campo.Replace(",", "_")), Literal)

        If ViewState(String.Format("O{0}", Campo)) IsNot Nothing AndAlso ViewState(String.Format("O{0}", Campo)).ToString = String.Format("{0} DESC", Campo) Then
            ViewState(String.Format("O{0}", Campo)) = String.Format("{0} ASC", Campo)
            Literal.Text = String.Format("<i class='fa fa-sort-asc' style='color:#999' ></i>")
        Else
            ViewState(String.Format("O{0}", Campo)) = String.Format("{0} DESC", Campo)
            Literal.Text = String.Format("<i class='fa fa-sort-desc' style='color:#999' ></i>")
        End If
        Orden = OrdenInicial & ViewState(String.Format("O{0}", Campo)).ToString
        ViewState("Orden") = Orden
        CargaGrid(Orden)
    End Sub


    Private Sub CargaGrid(Orden As String)
        If Orden <> String.Empty Then
            Dim DV As New DataView(CType(ViewState("DTBancos"), DataTable), "", Orden, DataViewRowState.CurrentRows)
            GvDatos.DataSource = DV.ToTable()
            DV.Dispose()
        Else
            GvDatos.DataSource = CType(ViewState("DTBancos"), DataTable)
        End If
        GvDatos.DataBind()
        UpDatos.Update()
    End Sub
#End Region
    Protected Sub LbPDF_Click(sender As Object, e As EventArgs)
        Imprime("PDF")
    End Sub
    Protected Sub LbExcel_Click(sender As Object, e As EventArgs)
        Imprime("Excel")
    End Sub
    Private Sub Imprime(Formato As String)

        If DtBan IsNot Nothing AndAlso DtBan.Rows.Count > 0 Then
            Dim Imagen As New System.IO.FileInfo(String.Format("{0}/Logo.png", UsuarioActual.Empresa.Ruta))

            Dim params As New List(Of ReportParameter)
            params.Add(New ReportParameter("NombreEmpresa", UsuarioActual.Empresa.Empresa))
            params.Add(New ReportParameter("UsuarioImprimio", UsuarioActual.Nombre))
            If Imagen.Exists Then
                params.Add(New ReportParameter("LogoPath", $"file://{Imagen.FullName}"))
            Else
                params.Add(New ReportParameter("LogoPath", ""))
            End If
            ImprimirPDF("Empresas/Grales/Formatos/RepBancos.rdlc", DtBan, params, "Reporte Bancos", Formato)
        Else
            Alert("No hay información para mostrar.", TipoMensaje.MsgAdvertencia)
        End If
    End Sub
End Class