Imports System.Data
Imports Extensiones
Imports Microsoft.Reporting.WebForms

Partial Class Compras_RepPUESinPago
    Inherits ClsPaginas

    Private Property DtDatos As DataTable
        Get
            DtDatos = DirectCast(ViewState("DtDatos"), DataTable)
        End Get

        Set(ByVal value As DataTable)
            ViewState("DtDatos") = value
        End Set
    End Property

    Private Sub Page_Load(sender As Object, e As EventArgs) Handles Me.Load

        If Not Page.IsPostBack Then
            InicializaValores()
        End If

    End Sub

    Private Sub InicializaValores()
        TxtFechaI.Text = FirstDayOfMonth(NowADS()).ToShortDateString
        TxtFechaF.Text = NowADS().LastDayOfMonth.ToShortDateString

        DdlSubProyecto.DataSource = GlobalDTSubProyectos(UsuarioActual.CveEmpresa)
        DdlSubProyecto.DataBind()
        DdlSubProyecto.Items.Insert(0, New ListItem("Todos", "-1"))

        CargaProveedores()
    End Sub

    Private Sub CargaProveedores()
        If (UsuarioActual.Empresa.Funcionalidad(105) = "1") Then
            DdlProveedor.setEsWebService(True)
            DdlProveedor.Attributes.Add("data-metodo", "getproveedores")
            DdlProveedor.SelectedText = "Todos"
            DdlProveedor.SelectedValue = "-1"
        Else
            DdlProveedor.setEsWebService(False)
            DdlProveedor.ddl.DataSource = GlobalDTCompProveedores(UsuarioActual.CveEmpresa)
            DdlProveedor.ddl.DataBind()
            DdlProveedor.ddl.Items.Insert(0, New ListItem("Todos", "-1"))
        End If
    End Sub

    Private Sub CargadatosGvPUES()

        Dim objCompras As New ClsCompras

        If objCompras.GetPUESinPago(TxtFechaI.Text.ToDate, TxtFechaF.Text.ToDate, DdlProveedor.SelectedValue.ToEntero, DdlSubProyecto.SelectedValue.ToEntero, UsuarioActual.CveEmpresa, UsuarioActual.CveUsuario) Then
            GvPUES.DataSource = objCompras.DtResultados
            DtDatos = objCompras.DtResultados
        Else
            GvPUES.DataSource = Nothing
        End If

        objCompras.Dispose()

        UPGvPUES.DataBind()
        UpGral.Update()

    End Sub

    Protected Sub btConsultar_Click(sender As Object, e As EventArgs)
        CargadatosGvPUES()
    End Sub

#Region "IMPRESION"
    Protected Sub LnkPDF_Click(sender As Object, e As EventArgs)
        GeneraImpresion()
    End Sub
    Protected Sub LnkExcel_Click(sender As Object, e As EventArgs)
        GeneraImpresion("Excel")
    End Sub

    Private Sub GeneraImpresion(Optional Formato As String = "PDF")

        Dim Imagen As New System.IO.FileInfo($"{UsuarioActual.Empresa.Ruta}/Logo.png")

        Dim FI As String = If(TxtFechaI.Text = "", "", $"&emsp;<b>Fecha Inicio:</b>&nbsp;{TxtFechaI.Text}")
        Dim FF As String = If(TxtFechaF.Text = "", "", $"&emsp;<b>Fecha Fin:</b>&nbsp;{TxtFechaF.Text}")
        Dim cliente As String = If(DdlProveedor.SelectedValue = "-1", "", $"&emsp;<b>Proveedor:</b>&nbsp;{DdlProveedor.SelectedText}")
        Dim subProy As String = If(DdlSubProyecto.SelectedValue = "-1", "", $"&emsp;<b>SubProyecto:</b>&nbsp;{DdlSubProyecto.SelectedItem.Text}")

        If DtDatos IsNot Nothing AndAlso DtDatos.Rows.Count > 0 Then

            Dim params As New List(Of ReportParameter)

            params.Add(New ReportParameter("NombreEmpresa", UsuarioActual.Empresa.Empresa))
            params.Add(New ReportParameter("UsuarioImprimio", UsuarioActual.Nombre))
            params.Add(New ReportParameter("AgrupadoPor", $"{FI}{FF}{cliente}{subProy}"))

            params.Add(New ReportParameter("LogoPath", If(Imagen.Exists, $"file://{Imagen.FullName}", "")))

            ImprimirPDF("Empresas/Grales/Formatos/CompPUEConSaldo.rdlc", DtDatos, params, "RepPUESinPago", Formato)
        Else
            Alert("No se encontraron datos con los filtros especificados", TipoMensaje.MsgAdvertencia)
        End If

    End Sub
#End Region
End Class