Option Explicit On
Option Strict On

Imports System.Data
Imports Extensiones
Imports Microsoft.Reporting.WebForms

Partial Class Inventarios_RepConsignaciones
    Inherits ClsPaginas

#Region "PROPIEDADES"
    Private Property DtDatos As DataTable
        Get
            Return CType(ViewState("DtDatos"), DataTable)
        End Get
        Set(value As DataTable)
            ViewState("DtDatos") = value
        End Set
    End Property

    Private Property DtConsignaciones As DataTable
        Get
            Return DirectCast(ViewState("DtConsignaciones"), DataTable)
        End Get
        Set(value As DataTable)
            ViewState("DtConsignaciones") = value
        End Set
    End Property
#End Region

    Protected Sub Page_Load(sender As Object, e As EventArgs) Handles Me.Load
        If Not Page.IsPostBack Then
            CargaCombos()
        End If
    End Sub

#Region "CARGA DATOS"
    Private Sub CargaCombos()
        'Llena Proveedores
        DdlProveedor.DataSource = GlobalDTCompProveedores(UsuarioActual.CveEmpresa)
        DdlProveedor.DataBind()
        DdlProveedor.Items.Insert(0, New ListItem("Seleccione el Proveedor", "-1"))

        CargaDdlRemisiones()
    End Sub

    Private Sub CargaDdlRemisiones()
        Dim ObjInventarios As New ClsInventarios
        If ObjInventarios.GetConsignacionesPendientes(DdlProveedor.SelectedValue.ToEntero, DdlTipoReporte.SelectedValue.ToEntero, -1, UsuarioActual.CveEmpresa) Then
            DdlRemisiones.DataSource = ObjInventarios.DtResultados.FiltraParametros("", "", {"CveConsignacion", "Consignacion"})
        End If
        ObjInventarios.Dispose()
        DdlRemisiones.DataBind()
        DdlRemisiones.Items.Insert(0, New ListItem("Todas", "-1"))
    End Sub
#End Region

    Protected Sub GvDatos_RowDataBound(sender As Object, e As GridViewRowEventArgs) Handles GvDatos.RowDataBound
        If e.Row.RowType = DataControlRowType.DataRow Then
            If e.Row.DBCampo("CvePS") = "" Then
                e.Row.CssClass = "SubTotales"
            End If
            'e.Row.FCLabel("LbCantidad").Text = If(DdlTipoReporte.SelectedValue = "1", e.Row.DBCampo("PorFacturar").FormatoNumero, e.Row.DBCampo("Disponibles").FormatoNumero)
        End If
    End Sub

    Protected Sub BtnConsultar_Click(sender As Object, e As EventArgs)
        If DdlTipoReporte.SelectedValue = "2" Then
            GvDatos.Columns(0).Visible = True
        Else
            GvDatos.Columns(0).Visible = False
        End If

        Dim ObjInventario As New ClsInventarios

        If ObjInventario.RepConsignaciones(DdlProveedor.SelectedValue.ToEntero, DdlTipoReporte.SelectedValue.ToEntero, DdlRemisiones.SelectedValue.ToEntero, UsuarioActual.CveEmpresa) Then
            DtDatos = ObjInventario.DtResultados
            DtConsignaciones = ObjInventario.DtResultados
        Else
            DtDatos = Nothing
            Alert("Ocurrió un error al consultar el reporte de consignaciones. Por favor vuelva a intentar.", TipoMensaje.MsgError)
        End If

        ObjInventario.Dispose()

        If DtDatos IsNot Nothing Then
            GvDatos.DataSource = DtDatos
            GvDatos.DataBind()
        End If
    End Sub

    Private Sub DdlProveedor_SelectedIndexChanged(sender As Object, e As EventArgs) Handles DdlProveedor.SelectedIndexChanged
        CargaDdlRemisiones()
        UpFiltros.Update()
    End Sub

    Private Sub DdlTipoReporte_SelectedIndexChanged(sender As Object, e As EventArgs) Handles DdlTipoReporte.SelectedIndexChanged
        CargaDdlRemisiones()
        UpFiltros.Update()
    End Sub

#Region "PDF"

    Private Sub LnkPdf_Click(sender As Object, e As EventArgs) Handles LnkPdf.Click
        If DtConsignaciones IsNot Nothing Then
            Dim StrFiltro As New StringBuilder
            If DdlProveedor.SelectedValue <> "-1" Then StrFiltro.AppendFormat("<b>Proveedor</b>: {0}", DdlProveedor.SelectedItem.Text)
            If DdlTipoReporte.SelectedValue <> "-1" Then StrFiltro.AppendFormat("&emsp;<b>Tipo Reporte</b>: {0}", DdlTipoReporte.SelectedItem.Text)
            If DdlRemisiones.SelectedValue <> "-1" Then StrFiltro.AppendFormat("&emsp;<b>Cliente</b>: {0}", DdlRemisiones.SelectedItem.Text)

            Dim Imagen As New System.IO.FileInfo($"{UsuarioActual.Empresa.Ruta}/Logo.png")
            Dim logouri = String.Format("{0}://{1}:{2}/Empresas/{3}/Logo.png", Request.Url.Scheme, Request.Url.Host, Request.Url.Port, UsuarioActual.CveEmpresa)

            Dim params As New List(Of ReportParameter)
            params.Add(New ReportParameter("NombreEmpresa", UsuarioActual.Empresa.Empresa))
            params.Add(New ReportParameter("UsuarioImprimio", UsuarioActual.Nombre))
            params.Add(New ReportParameter("FechaImpresion", Now.ToDateTime.ToShortDateString))
            params.Add(New ReportParameter("Filtros", StrFiltro.ToString))

            params.Add(New ReportParameter("LogoPath", If(Imagen.Exists, $"file://{Imagen.FullName}", "")))

            ImprimirPDF("Empresas/Grales/Formatos/RepConsignaciones.rdlc", DtConsignaciones, params, String.Format("ReporteConsignaciones-{0}", Now.ToDateTime.ToShortDateString))

        Else
            Alert("No hay datos consultados", TipoMensaje.MsgAdvertencia)
        End If
    End Sub

#End Region

#Region "EXCEL"
    Private Sub ImgExcel_Click(sender As Object, e As EventArgs) Handles ImgExcel.Click
        GvDatos.ExportToExcel("Reporte de Consignaciones" & Now.ToShortDateString)
    End Sub
#End Region

End Class