Commit inicial Ventas Productivo

Inventarios/RepOcInvMoto.aspx.vb

@@ -0,0 +1,115 @@
+Option Explicit On
+Option Strict On
+
+Imports System.Data
+Imports Extensiones
+Imports Microsoft.Reporting.WebForms
+
+Partial Class Inventarios_RepOcInvMoto
+    Inherits ClsPaginas
+
+    Private Sub Inventarios_RepOcInv_Load(sender As Object, e As EventArgs) Handles Me.Load
+        If Not Page.IsPostBack Then
+
+            InicializaValores()
+            cargaDatos()
+
+        End If
+    End Sub
+
+#Region "  INICIALIZA VALORES  "
+    Private Sub InicializaValores()
+        'Llenar dropdownlist de proveedores
+        DdlProveedor.DataSource = GlobalDTCompProveedores(UsuarioActual.CveEmpresa)
+        DdlProveedor.DataBind()
+        DdlProveedor.Items.Insert(0, New ListItem("Todos", "-1"))
+
+        DdlAlmacen.DataSource = GlobalDTAlmacenUsuarios(UsuarioActual.CveUsuario, UsuarioActual.CveEmpresa, -1).FiltraParametros("CveTipoAlmacen IN (1,2)")
+        DdlAlmacen.DataBind()
+        DdlAlmacen.Items.Insert(0, New ListItem("Seleccione", "-1"))
+
+        TxtFechaF.Text = Now.ToString("dd/MM/yyyy")
+        TxtFechaI.Text = Now.AddMonths(-1).ToString("dd/MM/yyyy")
+
+    End Sub
+#End Region
+
+#Region "PROPIEDADES"
+    Private Property DtOCMovimientos As DataTable
+        Get
+            Return DirectCast(ViewState("DtOCMovimientos"), DataTable)
+        End Get
+        Set(value As DataTable)
+            ViewState("DtOCMovimientos") = value
+        End Set
+    End Property
+
+#End Region
+
+#Region "  CARGA DATOS  "
+    Protected Sub btConsultar_Click(sender As Object, e As EventArgs) Handles btConsultar.Click
+        cargaDatos()
+    End Sub
+    Private Sub cargaDatos()
+        Dim Folio As String
+        Dim Fini As Date
+        Dim Ffin As Date
+
+        Folio = If(TxtFolio.Text.Trim.Length > 0, TxtFolio.Text.Trim, "-1")
+        Fini = If(IsDate(TxtFechaI.Text), TxtFechaI.Text.ToDate, MinFecha)
+        Ffin = If(IsDate(TxtFechaF.Text), TxtFechaF.Text.ToDate, MaxFecha)
+
+        Dim objInventario As New ClsInventarios
+        If objInventario.RepOcInvMoto(Folio, Fini, Ffin, DdlProveedor.SelectedValue.ToEntero, DdlAlmacen.SelectedValue.ToEntero, UsuarioActual.Empresa.CveEmpresa) Then
+            Gv.DataSource = objInventario.DtResultados
+            DtOCMovimientos = objInventario.DtResultados
+        Else
+            Gv.DataSource = Nothing
+        End If
+        Gv.DataBind()
+        objInventario.Dispose()
+
+        UPGv.Update()
+    End Sub
+
+#End Region
+
+
+#Region "  EXCEL  "
+    Private Sub LnkExportar_Click(sender As Object, e As EventArgs) Handles LnkExportar.Click
+        Gv.ExportToExcel("OCMovimientos")
+    End Sub
+#End Region
+
+#Region "PDF"
+    Private Sub LnkPdf_Click(sender As Object, e As EventArgs) Handles LinkPDF.Click
+        If DtOCMovimientos IsNot Nothing Then
+            Dim StrFiltro As New StringBuilder
+            If DdlProveedor.SelectedValue <> "-1" Then StrFiltro.AppendFormat("<b>Proveedor</b>: {0}", DdlProveedor.SelectedItem.Text)
+            If DdlAlmacen.SelectedValue <> "-1" Then StrFiltro.AppendFormat("<b>Almacen</b>: {0}", DdlAlmacen.SelectedItem.Text)
+
+            Dim Imagen As New System.IO.FileInfo(String.Format("{0}/Logo.png", UsuarioActual.Empresa.Ruta))
+            Dim logouri = String.Format("{0}://{1}:{2}/Empresas/{3}/Logo.png", Request.Url.Scheme, Request.Url.Host, Request.Url.Port, UsuarioActual.CveEmpresa)
+
+            If TxtFechaI.Text <> "" Then StrFiltro.AppendFormat("&emsp;<b>Fecha Inicio </b>: {0}", TxtFechaI.Text.ToDate.ToShortDateString)
+            If TxtFechaF.Text <> "" Then StrFiltro.AppendFormat("&emsp;<b>Fecha Fin </b>: {0}", TxtFechaF.Text.ToDate.ToShortDateString)
+            If TxtFolio.Text <> "" Then StrFiltro.AppendFormat("&emsp;<b>Folio OC</b>: {0}", TxtFolio.Text)
+
+            Dim params As New List(Of ReportParameter)
+            params.Add(New ReportParameter("NombreEmpresa", UsuarioActual.Empresa.Empresa))
+            params.Add(New ReportParameter("UsuarioImprimio", UsuarioActual.Nombre))
+            params.Add(New ReportParameter("FechaImpresion", Now.ToDateTime.ToShortDateString))
+            params.Add(New ReportParameter("Filtros", StrFiltro.ToString))
+            If Imagen.Exists Then
+                params.Add(New ReportParameter("LogoPath", logouri))
+            Else
+                params.Add(New ReportParameter("LogoPath", ""))
+            End If
+            ImprimirPDF("Empresas/Grales/Formatos/RepOCInvMoto.rdlc", DtOCMovimientos, params, String.Format("ReporteOCMovimientos-{0}", Now.ToDateTime.ToShortDateString))
+        Else
+            Alert("No hay datos consultados", TipoMensaje.MsgAdvertencia)
+        End If
+    End Sub
+#End Region
+
+End Class